Se rendre au contenu

Retrouver automatiquement le SIREN de ses clients avec Excel

Une macro Excel et le service gratuit Recherche d'entreprises de l'État pour compléter les SIREN de tout un fichier clients avant la facturation électronique, puis les remettre dans votre logiciel.
8 juillet 2026 par
Retrouver automatiquement le SIREN de ses clients avec Excel
DIGITALSACE, Rébecca TINCHON

Avec la réforme de la facturation électronique, chaque facture doit, ou devra bientôt, mentionner le numéro SIREN du client, et les plateformes s'en servent pour acheminer les factures. Si votre fichier clients contient des centaines de fiches sans SIREN, les chercher une par une sur Internet peut prendre des jours.

Voici une astuce simple pour faire le gros du travail automatiquement, depuis Excel, grâce à un service gratuit de l'État : l'API Recherche d'entreprises. Ensuite, on vérifie, et on remet les numéros dans son logiciel.

L'astuce fonctionne quel que soit votre logiciel de gestion. Elle demande Excel pour Windows (version 2013 ou plus récente) ; aucune compétence en programmation n'est nécessaire.

Le principe

L'État met à disposition une base des entreprises françaises, que l'on peut interroger librement par Internet. On lui donne un nom d'entreprise et un code postal, elle renvoie l'entreprise qui correspond le mieux, avec son SIREN. Une macro Excel pose la question pour chaque ligne de votre fichier, et écrit la réponse à côté.

Seuls le nom de l'entreprise et son code postal sont envoyés, des informations publiques. Le service accepte jusqu'à 7 demandes par seconde ; la macro en fait 5 au maximum pour rester dans les clous.

Préparer le fichier

Exportez vos clients depuis votre logiciel dans un fichier Excel, avec au moins :

  • un identifiant , pour pouvoir remettre les SIREN au bon endroit ensuite (avec Odoo, voir plus bas comment obtenir la bonne colonne) ;
  • la raison sociale ;
  • le code postal ;
  • une colonne vide pour le SIREN, suivie d'une colonne vide pour le nom trouvé, qui servira à vérifier.

Laissez de côté les clients étrangers et les particuliers : ils n'ont pas de SIREN.

Lancer la macro

  • Affichez l'onglet Développeur : clic droit sur le ruban, « Personnaliser le ruban », cochez « Développeur » dans la colonne de droite, puis OK.
  • Dans l'onglet Développeur, cliquez sur Visual Basic, puis sur Insertion, Module.
  • Collez le code ci-dessous dans la page blanche.
  • En haut du code, indiquez les numéros de vos colonnes (A = 1, B = 2, C = 3…) et la première ligne de données.
  • Revenez sur votre feuille, puis lancez la macro : Développeur, Macros, « ExtraireSiren », Exécuter.

La barre d'état, en bas d'Excel, indique la ligne en cours. Les lignes déjà remplies sont sautées : on peut relancer la macro sans tout refaire. Pour retenter une ligne en erreur ou « Non trouvé », videz sa case SIREN avant de relancer.

Les codes postaux qui commencent par 0 (départements 01 à 09) sont gérés, même quand Excel a supprimé le zéro.

Sub ExtraireSiren()
    ' À ADAPTER : numéros des colonnes (A = 1, B = 2...)
    Const COL_NOM As Integer = 2       ' raison sociale
    Const COL_CP As Integer = 3        ' code postal
    Const COL_SIREN As Integer = 4     ' SIREN (le nom trouvé ira dans la colonne suivante)
    Const LIGNE_DEPART As Long = 2     ' première ligne de données

    Dim http As Object, i As Long, derniere As Long
    Dim url As String, cp As String, statut As Integer, t As Single
    Set http = CreateObject("MSXML2.XMLHTTP")
    derniere = Cells(Rows.Count, COL_NOM).End(xlUp).Row

    For i = LIGNE_DEPART To derniere
        If Cells(i, COL_SIREN).Value = "" And Cells(i, COL_NOM).Value <> "" Then
            ' Code postal : sans espaces, et le zéro remis en tête si Excel l'a supprimé (01000 devenu 1000)
            cp = Replace(CStr(Cells(i, COL_CP).Value), " ", "")
            If Len(cp) = 4 Then cp = "0" & cp
            url = "https://recherche-entreprises.api.gouv.fr/search?q=" & _
                  Application.EncodeURL(Cells(i, COL_NOM).Value) & "&per_page=1"
            If cp <> "" Then url = url & "&code_postal=" & cp
            Application.StatusBar = "Ligne " & i & " / " & derniere & " : " & Cells(i, COL_NOM).Value
            Do
                ' En cas de coupure réseau, on note l'erreur au lieu d'arrêter la macro
                On Error Resume Next
                http.Open "GET", url, False
                http.Send
                If Err.Number <> 0 Then
                    statut = 0
                    Err.Clear
                Else
                    statut = http.Status
                End If
                On Error GoTo 0
                If statut = 429 Then
                    ' Trop de demandes : on patiente une minute
                    Application.StatusBar = "Limite atteinte, pause d'une minute..."
                    Application.Wait Now + TimeValue("00:01:00")
                End If
            Loop While statut = 429

            If statut = 200 Then
                Cells(i, COL_SIREN).NumberFormat = "@"   ' en texte, pour garder les zéros en tête
                Cells(i, COL_SIREN).Value = LireChamp(http.ResponseText, "siren")
                Cells(i, COL_SIREN + 1).Value = LireChamp(http.ResponseText, "nom_complet")
            ElseIf statut = 0 Then
                Cells(i, COL_SIREN).Value = "Erreur réseau"
            Else
                Cells(i, COL_SIREN).Value = "Erreur " & statut
            End If

            ' Pause de 0,2 seconde : 5 demandes par seconde au maximum
            t = Timer
            Do While Timer < t + 0.2 And Timer >= t   ' la 2e condition évite de bloquer à minuit
                DoEvents
            Loop
        End If
    Next i

    Application.StatusBar = False
    MsgBox "Terminé. Vérifiez les noms trouvés avant d'importer les SIREN.", vbInformation
End Sub

Function LireChamp(json As String, champ As String) As String
    ' Renvoie la valeur du premier champ trouvé dans la réponse
    Dim debut As Long, fin As Long
    debut = InStr(json, """" & champ & """:""")
    If debut = 0 Then
        LireChamp = "Non trouvé"
    Else
        debut = debut + Len(champ) + 4
        fin = InStr(debut, json, """")
        LireChamp = Mid(json, debut, fin - debut)
    End If
End Function

Vérifier les résultats

La macro fait environ les trois quarts du travail, mais elle prend l'entreprise dont le nom correspond le mieux : elle peut se tromper d'entreprise quand deux sociétés ont des noms voisins dans la même ville. D'où la colonne du nom trouvé :

  • comparez rapidement la raison sociale et le nom trouvé, et corrigez les lignes qui ne correspondent pas ;
  • pour les lignes « Non trouvé », cherchez à la main sur l'annuaire des entreprises (annuaire-entreprises.data.gouv.fr), souvent à cause d'un nom commercial différent de la raison sociale ;
  • pour les entreprises qui ont plusieurs établissements, vérifiez qu'il vous faut bien le SIREN (l'entreprise) et non le SIRET (l'établissement).

Remettre les SIREN dans votre logiciel

Une fois le fichier vérifié, réimportez les numéros grâce à l'identifiant de chaque client.

Avec Odoo, attention aux doublons : l'import ne met à jour une fiche existante que grâce à la colonne ID (l'identifiant d'Odoo), pas avec une simple référence interne. Faites donc votre export depuis la liste des contacts en cochant « Je souhaite mettre à jour des données (export compatible import) » : la colonne ID est ajoutée. Après la macro, importez le fichier sur la liste des contacts, en faisant correspondre la colonne ID et la colonne SIREN (ou SIRET) aux bons champs. Essayez d'abord sur quelques lignes.

C'est aussi le bon moment pour nettoyer le fichier clients : doublons, anciennes adresses, entreprises fermées.

L'essentiel à retenir

  • Le SIREN des clients devient indispensable avec la facturation électronique.
  • Un service gratuit de l'État permet de le retrouver à partir du nom et du code postal.
  • La macro Excel fait le gros du travail, ligne par ligne.
  • On vérifie les noms trouvés avant de réimporter les numéros.

Vous préférez qu'on s'en occupe ?

On peut vous aider à compléter et nettoyer votre fichier clients, puis à le remettre dans Odoo, avant le passage à la facturation électronique. Parlons de votre Odoo.